home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / lt1208 < prev    next >
Encoding:
Text File  |  1996-07-09  |  4.0 KB  |  127 lines
  1. * 
  2. * Linear Technology LT1208 op amp model  
  3. * Written: 12-09-1992 09:06:32 Type: Bipolar NPN input, internal comp.
  4. * Modified by G.F. to add Cload compensation network and freq. shaping
  5. * Typical specs: 
  6. * Vos=5.0E-04, Ib=4.0E-06, Ios=1.0E-07, GBP=4.5E+07Hz, Phase mar.= 50 deg, 
  7. * SR(-)=4.0E+02V/us, SR(+)=4.0E+02V/us, Av= 77.0dB, CMRR=100.0dB, 
  8. * Vsat(+)=1.300V, Vsat(-)=1.700V, Isc=+40/-40mA, Rout=50ohms, Iq=7.00mA.
  9. * 
  10. * Connections: + - V+V-O 
  11. .SUBCKT LT1208 3 2 7 4 6 
  12. * INPUT
  13. RC1 7  80 9.9909E+02
  14. RC2 7  90 9.9909E+02
  15. Q1  80 2  10 QM1 
  16. Q2  90 3  11 QM2 
  17. CIN 2  3  2.0000E-12
  18. C1  80 90 0.265E-12
  19. *INPUT POLE AT 300MHZ
  20. RE1 10 12 +9.5717E+02
  21. RE2 11 12 +9.5717E+02
  22. IEE 12 4  1.4240E-03
  23. RE  12 0  1.4045E+05
  24. * INTERMEDIATE
  25. *MODS: GA DEPENDENCE INVERTED (POLARITY SWAPPED)
  26. *      R2 INCREASED TO 7MOHM (ALL GAIN IN ONE STAGE)
  27. *      C2 TIED TO GROUND (WAS NODE 1), REDUCED TO 3.11PF FROM 3.54PF 
  28. *      GB POLARITY REVERSED, GB=1/R02 FOR GAIN OF 1 
  29. *      RF, CF ADDED FOR CLOAD NETWORK (REDUCES VALUE OF C2)
  30. *      REVERSE POLARITY OF GNL,GPL,GCL,GCM FOR LIMITING BECAUSE OF GA REVERSAL
  31. *      ADD MULTIPLE POLES AND A ZERO BETWEEN GA STAGE AND GB STAGE
  32. GCM 8  0  12 0  1.0009E-08
  33. GA  8  0  90 80 1.0009E-03
  34. R2  8  0  7.35E+06
  35. C2  8  0  3.11E-12
  36. *POLE AT 300MHZ
  37. GX1 0  28 8  0  1E-06
  38. RX1 28 0  1E+06
  39. CX1 28 0  0.53E-15
  40. *POLE AT 300MHZ
  41. GX2 0  38 28 0  1E-06
  42. RX2 38 0  1E+06
  43. CX2 38 0  0.53E-15
  44. *POLE AT 300MHZ
  45. GX3 0  48 38 0  1E-06
  46. RX3 48 0  1E+06
  47. CX3 48 0  0.53E-15  
  48. *ZERO AT 60MHZ
  49. GX4 0  58 48 0  1E-06
  50. RX4 58 59 1E+06
  51. LX4 59 0  2.65E-03
  52. *POLE AT 120MHZ
  53. GX5 0  68 58 0  1E-06
  54. RX5 68 0 1E+06
  55. CX5 68 0 1.33E-15
  56. *POLE AT 300MHZ
  57. GX6 0  78 68 0  1E-06
  58. RX6 78 0  1E+06
  59. CX6 78 0  0.53E-15
  60. *
  61. GB  0  1  78 0  20.4E-03
  62. RO2 1  0  49
  63. RF  8  99 2400
  64. CF  99 6  5E-12
  65. * OUTPUT 
  66. RSO 1  6  1.0000E+00
  67. ECL 18 0  1  6  2.3987E+01
  68. GCL 8  0  20 0  1.0000E+00
  69. RCL 20 0  1.0000E+01
  70. D1  18 19 DM1  
  71. VOD1 19 20 5.9605E-08
  72. D2  20 21 DM1  
  73. VOD2 21 18 5.9605E-08
  74. * 
  75. D3A 131 70 DM3 
  76. D3B 13 131 DM3 
  77. GPL 8  0  70 7  1.0000E+00
  78. VC  13 6  2.7909E+00
  79. RPLA 7  70 1.0000E+01
  80. RPLB 7  131 1.0000E+03
  81. D4A 60 141 DM3 
  82. D4B 141 14  DM3 
  83. GNL 8  0  60 4  1.0000E+00
  84. VE  6  14 3.1909E+00
  85. RNLA 60 4  1.0000E+01
  86. RNLB 141 4  1.0000E+03
  87. * 
  88. IP  7  4  5.5760E-03
  89. DSUB 4  7  DM2  
  90. * MODELS 
  91. .MODEL QM1 NPN (IS=8.0000E-16 BF=1.7481E+02)
  92. .MODEL QM2 NPN (IS=8.1240E-16 BF=1.7924E+02)
  93. .MODEL DM1  D   (IS=1.0000E-20)
  94. .MODEL DM2  D   (IS=8.0000E-16 BV=4.3200E+01)
  95. .MODEL DM3  D   (IS=1.0000E-16)
  96. .ENDS LT1208
  97. * 
  98. * - - - - - * FINI LT1208 * - - - - - * [OAMM VN02 10/29/90]
  99. ***
  100. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1993
  101. *                       All rights reserved.
  102. * 
  103. *   Linear Technology Corporation hereby grants the users of this
  104. * macromodel a non-exclusive, nontransferrable license to use this
  105. *            macromodel under the following conditions:
  106. * 
  107. * The user agrees that this macromodel is licensed from Linear
  108. * Technology and agrees that the macromodel may be used, loaned,
  109. * given away or included in other model libraries as long as this
  110. * notice and the model in its entirety and unchanged is included.
  111. * No right to make derivative works or modifications to the
  112. * macromodel is granted hereby.  All such rights are reserved.
  113. * 
  114. * This model is provided as is.  Linear Technology makes no
  115. * warranty, either expressed or implied about the suitability or
  116. * fitness of this model for any particular purpose.  In no event
  117. * will Linear Technology be liable for special, collateral,
  118. * incidental or consequential damages in connection with or arising
  119. * out of the use of this macromodel.  It should be remembered that
  120. * models are a simplification of the actual circuit.
  121. * 
  122. * Linear Technology reserves the right to change these macromodels
  123. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  124. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  125. * datasheets on the actual amplifiers or the latest macromodels.
  126. * 
  127. * ----------------------------------------------------------------------- *